13.4.創建GroupingCollection

2024-04-27 13:52:16

字體：大中小

來源：轉載

供稿：網友

13.4.1. 問題
我想基于集合中數據項的某個屬性創建唯一的分組數據
13.4.2. 解決辦法
傳遞一個Array 參數給GroupingCollection 構造器或設置GroupingCollection 對象的source屬性。
13.4.3. 討論
任何GroupingCollection 都有一個Grouping 對象實例，其擁有對應的GroupingField，定義了將用來生成分組數據的數據對象屬性。你可以根據對象屬性使用GroupingCollection 進行數據分組。要對數據對象的state 和region 屬性進行分組，具體如下：

-ActionScript

var groupingColl:GroupingCollection = new GroupingCollection();
groupingColl.source = [{city:"Columbus", state:"Ohio", region:"East"},
{city:"Cleveland", state:"Ohio", region:"East"}, {city:"Sacramento",
state:"California", region:"West"}, {city:"Atlanta", state:"Georgia",
region:"South"}];

對state 屬性進行分組，首先創建具有相同state 的所有對象分組，創建Grouping 實例，傳遞GroupingField 對象數組給Grouping 實例的fields：

-ActionScript

var groupingInst:Grouping = new Grouping();
groupingInst.fields = [new GroupingField("state")];
groupingColl.grouping = groupingInst;
groupingColl.refresh(false);

Grouping 實例初始化后，設置GroupingCollection 的grouping 屬性為groupingInst，然后刷新，集合將根據state 屬性值對集合所有數據進行分組：

-XML

<mx:VBox xmlns:mx="http://www.adobe.com/2006/mxml" width="400" height="300" creationComplete="init()">
<mx:Script>
<![CDATA[
import mx.collections.Grouping;
import mx.collections.GroupingField;
import mx.collections.GroupingCollection;
[Bindable]
private var groupingColl:GroupingCollection;
private function init():void {
groupingColl = new GroupingCollection();
groupingColl.source = [
{city:"Columbus",state:"Ohio",region:"East"},
{city:"Cleveland", state:"Ohio", region:"East"},
{city:"Sacramento",state:"California",region:"West"},
{city:"Atlanta",state:"Georgia", region:"South"}];
var groupingInst:Grouping = new Grouping();
groupingInst.fields = [new GroupingField("state")];
groupingColl.grouping = groupingInst;
groupingColl.refresh(false);
}
//設置好GroupingCollection的grouping屬性后，設置另外的分組將會覆蓋當前分組:
private function createRegionGrouping():void {
var groupingInst:Grouping = new Grouping();
groupingInst.fields =
[new GroupingField("region")];
groupingColl.grouping = groupingInst;
groupingColl.refresh(false);
}

]]>
</mx:Script>
<mx:AdvancedDataGrid dataProvider="{groupingColl}">
<mx:columns>
<mx:AdvancedDataGridColumn dataField="city"/>
</mx:columns>
</mx:AdvancedDataGrid>
<mx:Button click="createRegionGrouping()"/>
</mx:VBox>