23.17.創(chuàng)建系統(tǒng)托盤圖標(biāo)

2024-04-27 13:52:34

字體：大中小

供稿：網(wǎng)友

23.17.1.問題
我想讓應(yīng)用程序運(yùn)行在后臺，不需要主界面。
23.17.2.解決辦法
在<mx:WindowedApplication>根標(biāo)簽和描述文件里設(shè)置應(yīng)用程序的可見性為false，使用DockIcon和SystemTrayIcon類，添加自定義程序圖標(biāo)。
23.17.3.討論
是可以創(chuàng)建沒有主界面的應(yīng)用程序，且運(yùn)行在后臺。這些應(yīng)用程序出現(xiàn)在系統(tǒng)托盤或停靠欄里。Mac OS X 和Windows操作系統(tǒng)都支持應(yīng)用程序圖標(biāo)，只是規(guī)定有些差別。因此AIR 針對不同操作系統(tǒng)提供圖標(biāo)顯示類。DockIcon類是運(yùn)行在Mac OS X系統(tǒng)下而SystemTrayIcon類是在Windows下。要檢測哪一個圖標(biāo)被操作系統(tǒng)所支持，你可以使用NativeApplication 類的supportsDockIcon 和supportsSystemTrayIcon屬性。

DockIcon 和SystemTrayIcon 類都是繼承自flash.desktop.InteractiveIcon 抽象基類。

NativeApplication實例的icon屬性是指向操作系統(tǒng)支持的應(yīng)用程序圖標(biāo)類引用。你可以賦值圖形給icon的bitmaps屬性。Bitmaps數(shù)組里的元素都是BitmapData對象，其大小是操作系統(tǒng)所規(guī)定的大小。如果bitmaps屬性為空，則Mac OS X下默認(rèn)的圖標(biāo)會被使用而Windows系統(tǒng)下不會顯示圖標(biāo)在系統(tǒng)托盤上。

除了可以添加自定義應(yīng)用程序圖標(biāo)外，你還可以添加當(dāng)用戶點擊圖標(biāo)時顯示的本地的上下文菜單。在上下文菜單上，可以監(jiān)聽選擇項和運(yùn)行相應(yīng)的命令。下面的例子將運(yùn)行在系統(tǒng)托盤或停靠欄上，并提供一個命令用于關(guān)閉程序：

-XML

<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical"
visible="false" windowComplete="completeHandler();">
<mx:Script>
<![CDATA[
[Embed(source='assets/AIRApp_16.png')]
private var icon16:Class;
[Embed(source='assets/AIRApp_32.png')]
private var icon32:Class;
[Embed(source='assets/AIRApp_48.png')]
private var icon48:Class;
[Embed(source='assets/AIRApp_128.png')]
private var icon128:Class;
private function completeHandler():void {
var shellMenu:NativeMenu = createShellMenu();
var icon:InteractiveIcon = NativeApplication.nativeApplication.icon;
if ( NativeApplication.supportsDockIcon ) {
( icon as DockIcon ).menu = shellMenu;
}
else
{
( icon as SystemTrayIcon ).menu = shellMenu;
( icon as SystemTrayIcon ).tooltip = "My App" ;
}
var bitmaps:Array = [new icon16(), new icon32(), new icon48(), new icon128()];
icon.bitmaps = bitmaps;
}
private function createShellMenu():NativeMenu {
var menu:NativeMenu = new NativeMenu();
var quitCmd:NativeMenuItem = new NativeMenuItem( "Quit");
quitCmd.addEventListener(Event.SELECT,quitHandler );
menu.addItem( quitCmd );
return menu;
}
private function quitHandler( evt:Event ):void {
NativeApplication.nativeApplication.exit();
}

]]>
</mx:Script>
</mx:WindowedApplication>