ASP編程入門進階（十四）：Browser & Linking

2020-07-27 13:19:22

字體：大中小

來源：轉載

供稿：網友

一、Browser Capabilities組件

該組件最主要的作用是：提取識別客戶端瀏覽器的版本信息。

其原理是這樣的：當客戶端瀏覽器向服務器發送頁面請求時，同時會自動發送一個User Agent HTTP標題，而該標題是一個聲明瀏覽器及其版本的 ASCII 字符串。而Browser Capabilities組件就將User Agent映射到在文件Browscap.ini中所注明的瀏覽器 , 并通過BrowserType對象的屬性來識別客戶瀏覽器。

若該對象在 browscap.ini 文件中找不到與該標題匹配的項，那么將使用默認的瀏覽器屬性。若該對象既未找到匹配項且 browscap.ini 文件中也未指定默認的瀏覽器設置，則它將每個屬性都設為字符串 "UNKNOWN"。

在默認情況下，browscap.ini文件被存放在 WINDOWS/SYSTEM/INERSRV( 如果是95/98+PWS4) 或 NT/SYSTEM32/INERSRV( 如果是 NT) 目錄中，你可以自己編輯這個文本文件，以添加自己的屬性或者根據最新發布的瀏覽器版本的更新文件來修改該文件。

可以得出結論，Browser Capabilities組件也就是提取某個文件中的內容，然后比較得出顯示。具體該如何應用呢？

1，btinfo.asp

<%set bc=server.CreateObject("mswc.browsertype")%>
瀏覽器名稱是browser：<%=bc.browser%> 
瀏覽器版本是version：<%=bc.version%> 
瀏覽器主版本是majorver:<%=bc.majorver%> 
瀏覽器輔版本是minorver:<%=bc.minorver%> 
瀏覽器的運行平臺是platform：<%=bc.platform%>

很顯然“<%set bc=server.CreateObject("mswc.browsertype")%> ”就是進行的瀏覽器組件的建立
以下諸如“bc.browser”之類即為顯示瀏覽器的具體某個特性了。

2，btif.asp

<%set bc=server.CreateObject("mswc.browsertype")%>
<%if bc.frames=true then%>
瀏覽器支持多窗口(frames)顯示
<%else%>
瀏覽器不支持多窗口(frames)顯示
<%end if%>
 
<%if bc.backgroundsounds=true then%>
瀏覽器可以播放背景音樂(backgroundsounds)
<%else%>
瀏覽器不能播放背景音樂(backgroundsounds)
<%end if%>
 
<%if bc.tables=true then%>
瀏覽器支持表格(tables)顯示
<%else%>
瀏覽器不支持表格(tables)顯示
<%end if%>
 
<%if bc.beta=true then%>
你的瀏覽器是一測試版(beta)
<%else%>
你的瀏覽器是一正式版
<%end if%>
 
<%if bc.activexcotrols=true then %>
瀏覽器支持active控制
<%else%>
瀏覽器不支持active控制
<%end if%>
 
<%if bc.cookies=true then%>
瀏覽器支持cookie功能
<%else%>
瀏覽器不支持cookie功能
<%end if%>
 
<%if bc.vbscript=true then%>
瀏覽器支持vbscript
<%else%>
瀏覽器不支持vbscript
<%end if%>
 
<%if bc.jscript=true then%>
瀏覽器支持jscript
<%else%>
瀏覽器不支持jscript
<%end if%>

該代碼則是檢測當前瀏覽器對各類網頁技術的支持情況，那下面就可以根據某特定情況做相應變動

3，fram.asp

<%set bc=server.CreateObject("mswc.browsertype")
if bc.frames then
%>
<frameset rows="*,*">
<frame src="http://www.google.com">
<frame src="http://www.baidu.com">
</framest>
<%else%>
你的瀏覽器不支持框架
<%end if%>

很簡單的意思：如果當前瀏覽器支持框架則進行frameset的顯示，否則提示“你的瀏覽器不支持框架”

當然，需要提醒你的：不要過分依賴該組件，因為其只是提取browscap.ini里的值，而該值隨時可以被客戶修改，或者記錄過時，不能真實反映到瀏覽器的情況，慎用之。

二、Content Linking組件

曾經用DW做網頁都有這樣一個煩惱：新做了頁面，其它所有相關的頁都要重新再做一次超級鏈接。一次也就罷了，多了多了不禁覺得無用功做了不少。試想如果能有一個專門的文件來負責頁面的連接那該多好。

Content Linking 組件也就應運而生了。它非但可以使你在這些頁面中建立一個目錄表，而且還可以在它們中間建立動態連接，并自動生成和更新目錄表及先前和后續的 Web 頁的導航鏈接。

使用該組件，首先需要編寫一個目錄文件，也就是網頁網址的順序列表文件，它是一個文本文件，可以自由命名。其次，編寫一個ASP文件，根據目錄文件提供的信息自動生成帶超鏈的目錄頁。如果需要在每一頁上假如“向前或向后翻頁”的超鏈，就再編寫一個能自動生成翻頁超鏈的包含文件，可使用inc為擴展名,例如"Nlink.inc"。以后，在組內每一頁中包含它。

1，link.txt

redirect.asp?url=http://www.cnbruce.com/    cnbruce.com
redirect.asp?url=http://www.blueidea.com/    blueidea.com
redirect.asp?url=http://www.it365cn.com/    it365cn.com

該目錄文件的網址就是連接網址，文本就是連接文本了，需要注意的是中間采用Tab鍵進行分隔。

2，link.asp

<%Set objNextLink = Server.CreateObject("MSWC.Nextlink")%>
<%
intCount = objNextLink.GetListCount("link.txt")
For i = 1 To intCount
%>
<a href="<%=objNextLink.GetNthURL("link.txt", i) %>">
<%=objNextLink.GetNthDescription("link.txt", i) %>
</a>
 
<%Next%>

“Set objNextLink = Server.CreateObject("MSWC.Nextlink")”建立Nextlink組件的連接
“objNextLink.GetListCount("link.txt")”提取link.txt文件中的列表數目
“objNextLink.GetNthURL("link.txt",i)”提取link.txt文件中第i行文本的連接網址
“objNextLink.GetNthDescription("link.txt",i)”提取link.txt文件中第i行文本的連接文本

3，redirect.asp
也就是轉向文件了。

<%
Response.Clear
Response.Redirect Request.QueryString("url")
%>

呵呵，是不是覺得還沒用到“上一頁”、“下一頁”的功能。再來~！

4，link1.txt

1.asp    ASP編程入門進階（一）
2.asp    ASP編程入門進階（二）
3.asp    ASP編程入門進階（三）
4.asp    ASP編程入門進階（四）

主要功能是設置文本和連接

5，link1.inc

<%Set Nextlink=Server.CreateObject("MSWC.NextLink")
Response.write "當前文章索引號為" & NextLink.GetListIndex("link1.txt") & " "
Response.write "上一章的標題：" & NextLink.GetPreviousDescription("link1.txt") & " "
Response.write "下一章的標題：" & NextLink.GetNextDescription("link1.txt") & " "
count = NextLink.GetListCount("link1.txt")
Response.write "<a href="""&NextLink.GetNthUrl("link1.txt",1)&"""&>"&"第一章"&"</a> "
Response.write "<a href="""&NextLink.GetPreviousUrl("link1.txt")&"""&>"&"上一章"&"</a> "
Response.write "<a href="""&NextLink.GetNextUrl("link1.txt")&"""&>"&"下一章"&"</a> "
Response.write "<a href="""&NextLink.GetNthUrl ("link1.txt",count)&"""&>"&"最后一章"&"</a> "
%>

GetListCount(目標文件名) 顯示組件中包含的連接的文件數目。
GetListIndex(目標文件名) 顯示當前頁在這些連接文件中的前后位置索引值。
GetNextDescription(目標文件名) 顯示連接文件中下一個的描述。
GetNextURL(目標文件名) 顯示連接文件中的下一個文件的URL地址。
GetNthDescription(目標文件名, N) 顯示連接文件中第N個網頁的描述。
GetNthURL(目標文件名, N) 顯示連接文件中第N個網頁的文件URL地址。
GetPreviousDescription(目標文件名) 顯示連接文件中前一個文件的描述。
GetPreviousURL(目標文件名) 顯示連接文件中前一個文件的URL地址。

6，1.asp，2.asp，3.asp，4.asp

以下是具體內容

著就是一個很簡單的分頁程序了。當然接著的后面會有些更詳細更復雜的分頁，慢慢來吧，呵呵。

上一篇：ASP編程入門進階（十五）：組件Counters

下一篇：ASP編程入門進階（十三）：Ad & Content Rotator