VBScript教程 第八課 使用循環語句
2020-07-26 12:14:53
供稿：網友
使用循環重復執行代碼
循環用于重復執行一組語句。循環可分為三類：一類在條件變為 False 之前重復執行語句，一類在條件變為 True 之前重復執行語句，另一類按照指定的次數重復執行語句。
在 VBScript 中可使用下列循環語句：
Do...Loop： 當（或直到）條件為 True 時循環。
While...Wend： 當條件為 True 時循環。
For...Next： 指定循環次數，使用計數器重復運行語句。
For Each...Next： 對于集合中的每項或數組中的每個元素，重復執行一組語句。
使用 Do 循環
可以使用 Do...Loop 語句多次（次數不定）運行語句塊。當條件為 True 時或條件變為 True 之前，重復執行語句塊。
當條件為 True 時重復執行語句
While 關鍵字用于檢查 Do...Loop 語句中的條件。有兩種方式檢查條件：在進入循環之前檢查條件（如下面的 ChkFirstWhile 示例）；或者在循環至少運行完一次之后檢查條件（如下面的 ChkLastWhile 示例）。在 ChkFirstWhile 過程中，如果 myNum 的初始值被設置為 9 而不是 20，則永遠不會執行循環體中的語句。在 ChkLastWhile 過程中，循環體中的語句只會執行一次，因為條件在檢查時已經為 False。
Sub ChkFirstWhile()
Dim counter, myNum
counter = 0
myNum = 20
Do While myNum > 10
myNum = myNum - 1
counter = counter + 1
Loop
MsgBox "循環重復了 " & counter & " 次。"
End Sub
Sub ChkLastWhile()
Dim counter, myNum
counter = 0
myNum = 9
Do
myNum = myNum - 1
counter = counter + 1
Loop While myNum > 10
MsgBox "循環重復了 " & counter & " 次。"
End Sub
重復執行語句直到條件變為 True
Until 關鍵字用于檢查 Do...Loop 語句中的條件。有兩種方式檢查條件：在進入循環之前檢查條件（如下面的 ChkFirstUntil 示例）；或者在循環至少運行完一次之后檢查條件（如下面的 ChkLastUntil 示例）。只要條件為 False，就會進行循環。
Sub ChkFirstUntil()
Dim counter, myNum
counter = 0
myNum = 20
Do Until myNum = 10
myNum = myNum - 1
counter = counter + 1
Loop
MsgBox "循環重復了 " & counter & " 次。"
End Sub
Sub ChkLastUntil()
Dim counter, myNum
counter = 0
myNum = 1
Do
myNum = myNum + 1
counter = counter + 1
Loop Until myNum = 10
MsgBox "循環重復了 " & counter & " 次。"
End Sub
退出循環
Exit Do 語句用于退出 Do...Loop 循環。因為通常只是在某些特殊情況下要退出循環（例如要避免死循環），所以可在 If...Then...Else 語句的 True 語句塊中使用 Exit Do 語句。如果條件為 False，循環將照常運行。
在下面的示例中，myNum 的初始值將導致死循環。If...Then...Else 語句檢查此條件，防止出現死循環。
Sub ExitExample()
Dim counter, myNum
counter = 0
myNum = 9
Do Until myNum = 10
myNum = myNum - 1
counter = counter + 1
If myNum < 10 Then Exit Do
Loop
MsgBox "循環重復了 " & counter & " 次。"
End Sub
使用 While...Wend
While...Wend 語句是為那些熟悉其用法的用戶提供的。但是由于 While...Wend 缺少靈活性，所以建議最好使用 Do...Loop 語句。
使用 For...Next
For...Next 語句用于將語句塊運行指定的次數。在循環中使用計數器變量，該變量的值隨每一次循環增加或減少。
例如，下面的示例將過程 MyProc 重復執行 50 次。For 語句指定計數器變量 x 及其起始值與終止值。Next 語句使計數器變量每次加 1。
Sub DoMyProc50Times()
Dim x
For x = 1 To 50
MyProc
Next
End Sub
關鍵字 Step 用于指定計數器變量每次增加或減少的值。在下面的示例中，計數器變量 j 每次加 2。循環結束后，total 的值為 2、4、6、8 和 10 的總和。
Sub TwosTotal()
Dim j, total
For j = 2 To 10 Step 2
total = total + j
Next
MsgBox "總和為 " & total & "。"
End Sub
要使計數器變量遞減，可將 Step 設為負值。此時計數器變量的終止值必須小于起始值。在下面的示例中，計數器變量 myNum 每次減 2。循環結束后，total 的值為 16、14、12、10、8、6、4 和 2 的總和。
Sub NewTotal()
Dim myNum, total
For myNum = 16 To 2 Step -2
total = total + myNum
Next
MsgBox "總和為 " & total & "。"
End Sub
Exit For 語句用于在計數器達到其終止值之前退出 For...Next 語句。因為通常只是在某些特殊情況下（例如在發生錯誤時）要退出循環，所以可以在 If...Then...Else 語句的 True 語句塊中使用 Exit For 語句。如果條件為 False，循環將照常運行。
使用 For Each...Next
For Each...Next 循環與 For...Next 循環類似。For Each...Next 不是將語句運行指定的次數，而是對于數組中的每個元素或對象集合中的每一項重復一組語句。這在不知道集合中元素的數目時非常有用。
在以下示例中，Dictionary 對象的內容用于將文本分別放置在多個文本框中：
<HTML>
<HEAD><TITLE>窗體與元素</TITLE></HEAD>
<SCRIPT LANGUAGE="VBScript">
<!--
Sub cmdChange_onClick
Dim d '創建一個變量
Set d = createObject("Scripting.Dictionary")
d.Add "0", "Athens" '添加鍵和項目
d.Add "1", "Belgrade"
d.Add "2", "Cairo"
For Each I in d
Document.frmForm.Elements(I).Value = D.Item(I)
Next
End Sub
-->
</SCRIPT>
<BODY>
<CENTER>
<FORM NAME="frmForm"
<Input Type = "Text"><p>
<Input Type = "Text"><p>
<Input Type = "Text"><p>
<Input Type = "Text"><p>
<Input Type = "Button" NAME="cmdChange" VALUE="單擊此處"><p>
</FORM>
</CENTER>
</BODY>
</HTML>
