'/*=========================================================================
' * Intro       拖動(dòng)所有要轉(zhuǎn)換的gb2312編碼文件到這個(gè)文件上，程序會將它們自動(dòng)轉(zhuǎn)換為utf-8編碼文件
' * FileName    GB2312.To.UTF-8.vbs
' * Author      yongfa365
' * Version     v1.0
' * WEB         http://www.yongfa365.com
' * Email       yongfa365[at]qq.com 
' * LastModify  2007-10-04 10:42:53
' *==========================================================================*/

Set objArgs = WScript.Arguments
If objArgs.Count>0 Then
    If MsgBox("本程序僅支持GB2312到UTF-8的轉(zhuǎn)換"&vbCrLf&"如果您所拖動(dòng)的文件里有別的格式的文件請點(diǎn)“取消”", vbOKCancel + vbExclamation + vbDefaultButton2, "鄭重提醒!!!") = vbOK Then
        For I = 0 To objArgs.Count - 1
            FileUrl = objArgs(I)
            Call WriteToFile(FileUrl, ReadFile(FileUrl, "gb2312"), "utf-8")
        Next
    End If
Else
    MsgBox "請將您要轉(zhuǎn)換的“gb2312文件”拖到這個(gè)文件上"&vbCrLf&"程序會將它們自動(dòng)轉(zhuǎn)換為utf-8文件", vbInformation, "柳永法溫馨提示："
End If

'-------------------------------------------------
'函數(shù)名稱:ReadFile
'作用:利用AdoDb.Stream對象來讀取各種格式的文本文件
'----------------------------------------------------

Function ReadFile(FileUrl, CharSet)
    Dim Str
    Set stm = CreateObject("Adodb.Stream")
    stm.Type = 2
    stm.mode = 3
    stm.charset = CharSet
    stm.Open
    stm.loadfromfile FileUrl
    Str = stm.readtext
    stm.Close
    Set stm = Nothing
    ReadFile = Str
End Function

'-------------------------------------------------
'函數(shù)名稱:WriteToFile
'作用:利用AdoDb.Stream對象來寫入各種格式的文本文件
'參數(shù):FileUrl-文件相對路徑;Str-文件內(nèi)容;CharSet-編碼格式(utf-8,gb2312.....)
'----------------------------------------------------

Function WriteToFile (FileUrl, Str, CharSet)
    Set stm = CreateObject("Adodb.Stream")
    stm.Type = 2
    stm.mode = 3
    stm.charset = CharSet
    stm.Open
    stm.WriteText Str
    stm.SaveToFile FileUrl, 2
    stm.flush
    stm.Close
    Set stm = Nothing
End Function