本例為Flash AS3.0實例教程，在教程中我們將學習運用SoundMixer.computeSpectrum() 方法來構建簡單的聲音可視化程序（即波形圖），希望能給朋友們帶來幫助~~
AS3.0構建簡單的聲音可視化程序(波型圖)
使用 SoundMixer.computeSpectrum() 方法來顯示聲音波形圖
import flash.display.Graphics;
import flash.events.Event;
import flash.media.Sound;
import flash.media.SoundChannel;
import flash.media.SoundMixer;
import flash.net.URLRequest;
const PLOT_HEIGHT:int = 200;
const CHANNEL_LENGTH:int = 256;
var snd:Sound = new Sound();
var req:URLRequest = new URLRequest("月亮之上.mp3"); //配置聲音源文件地址(此為本地，可配置遠程)
snd.load(req);
var channel:SoundChannel;
channel = snd.play();
addEventListener(Event.ENTER_FRAME, onEnterFrame);
snd.addEventListener(Event.SOUND_COMPLETE, onPlaybackComplete);
var bytes:ByteArray = new ByteArray();
function onEnterFrame(event:Event):void
{
SoundMixer.computeSpectrum(bytes, false, 0);
var g:Graphics = this.graphics;
g.clear();
g.lineStyle(0, 0x6600CC);
g.beginFill(0x6600CC);
g.moveTo(0, PLOT_HEIGHT);
var n:Number = 0;
// left channel
for (var i:int = 0; i < CHANNEL_LENGTH; i++)
{
n = (bytes.readFloat() * PLOT_HEIGHT);
g.lineTo(i * 2, PLOT_HEIGHT - n);
}
g.lineTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
g.endFill();
// right channel
g.lineStyle(0, 0xCC0066);
g.beginFill(0xCC0066, 0.5);
g.moveTo(CHANNEL_LENGTH * 2, PLOT_HEIGHT);
for (i = CHANNEL_LENGTH; i > 0; i--)
{
n = (bytes.readFloat() * PLOT_HEIGHT);
g.lineTo(i * 2, PLOT_HEIGHT - n);
}
g.lineTo(0, PLOT_HEIGHT);
g.endFill();
}
function onPlaybackComplete(event:Event)
{
removeEventListener(Event.ENTER_FRAME, onEnterFrame);
}
先加載并播放一個聲音文件，然后在播放聲音的同時偵聽將觸發 onEnterFrame() 方法的 Event.ENTER_FRAME 事件。onEnterFrame() 方法先調用 SoundMixer.computeSpectrum() 方法，后者將聲音波形數據存儲在 bytes ByteArray 對象中。
聲音波形是使用矢量繪圖 API 繪制的。 for 循環將循環訪問第一批 256 個數據值（表示左立體聲聲道），然后使用 Graphics.lineTo() 方法繪制一條從每個點到下一個點的直線。第二個 for 循環將循環訪問下一批 256 個值，此時按相反的順序（從右到左）對它們進行繪制。生成的波形圖可能會產生有趣的鏡像圖像效果。
以上就是Flash AS3.0構建聲音可視化程序(波形圖)教程，希望大家喜歡！
