于是把我的收集整理后發出來給大家共享一下。
說明：
收集整理： 隨風 @bbs.bathome.cn 2008-04-15
第一個代碼 作者：Will Sort 出自：cn-dos
第二、三、四、個代碼 作者：namejm 出自：cn-dos
第五個為 bat 結合 vbs 代碼，作者及出處都不詳。
其中第一及第五個代碼，輸入負數為：追溯指定日期以后的天數。
第二、三、四個代碼，未作測試，但輸入正整數是可以的。也就是追溯指定日期以前的天數。
代碼一、
作者：Will Sort
復制代碼 代碼如下:
:: DateDel2.bat - 刪除指定路徑下指定日數以前修改的文件
:: 作者：Will Sort - 2005-9-2 - CMD@WinXP 出自：cn-dos
:: 注意事項：變量 tian 為指定日數，昨天為1，前天為2，依次類推
:: 核心算法：Ritchie Lawrence, updated 2002-08-13. Version 1.1
::
@echo off & setlocal ENABLEEXTENSIONS
call :Date2Day %date:~0,10% sdays
rem 下行的%tian%代表天數.
set /p tian= 請指定要追溯的天數：
set /a sdays-=tian
call :Day2Date %sdays% difdate
echo.&echo.
echo 指定的日期是： %date:~0,10%
echo.
echo %tian% 天前的日期是：%difdate%
echo.&pause
exit
:Date2Day
setlocal ENABLEEXTENSIONS
for /f "tokens=1-3 delims=/-, " %%a in ('echo/%1') do (
set yy=%%a & set mm=%%b & set dd=%%c
)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %2=%j%&goto :EOF
:Day2Date
setlocal ENABLEEXTENSIONS
set /a i=%1,a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%-%mm%-%dd%&goto :EOF
代碼二、
以下三個代碼作者全是 namejm
復制代碼 代碼如下:
:: 作者： namejm 榮譽版主 出自：cn-dos
@echo off
:: 求N天前的日期
:: 思路：
:: 模擬手工運算，用日期數減去天數，差值為負時向高位借1。
:: 特點：
:: 代碼簡潔，容易理解，速度快慢取決于指定的天數大小
:: 日期可以帶星期，但是，必須以年月日的順序排列
:: 年份必須是四位，否則會出錯
@echo off
:Main
cls
set day=%date%
set days=0
echo.&echo.
echo 指定的日期是：%day%
echo.
set /p input= 請指定要追溯的天數：
setlocal enabledelayedexpansion
:: 提取日期
for /f "tokens=1-3 delims=-/. " %%i in ("%day%") do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100
)
set /a sd-=input
if %sd% leq 0 call :count
cls
echo.&echo.
echo 指定的日期是：%day%
echo.
set sm=0%sm%
set sd=0%sd%
echo %input% 天前的日期是：%sy%-%sm:~-2%-%sd:~-2%
pause>nul
goto Main
:count
set /a sm-=1
if !sm! equ 0 set /a sm=12, sy-=1
call :days
set /a sd+=days
if %sd% leq 0 goto count
goto :eof
:days
:: 獲取指定月份的總天數
set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
set /a max=28+leap
set num=0
set str=31 %max% 31 30 31 30 31 31 30 31 30 31
for %%i in (%str%) do (
set /a num+=1
if %sm% equ !num! set days=%%i&goto :eof
)
goto :eof
代碼三
復制代碼 代碼如下:
@echo off
:: 作者： namejm 榮譽版主 出自：cn-dos
:: 求N天前的日期
:: 思路：
:: 把當前日期轉換為天數
:: 用當前天數減去N天
:: 把結果再轉換為日期
:: 具體操作是：
:: 逐年計算天數
:: 特點：
:: 代碼簡潔，容易理解，速度較慢，但是不受指定天數大小的影響
setlocal enabledelayedexpansion
:Main
cls
:: 日期可以帶星期，但是，必須以年月日的順序排列
:: 年份必須是四位，否則會出錯
set day=%date%
set days=0
echo.&echo.
echo 指定的日期是：%day%
echo.
set /p input= 請指定要追溯的天數：
rem ========把指定日期轉換為天數========
:: 提取日期
for /f "tokens=1-3 delims=-/. " %%i in ("%day%") do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100
)
:: 把年份轉化為天數
for /l %%i in (1,1,%sy%) do (
set /a leap="^!(%%i %% 4) & ^!(^!(%%i %% 100)) | ^!(%%i %% 400)"
set /a days=days+365+leap
)
:: 把月份轉化為天數
set /a num=0, mday=0, max=28+leap
set str=0 31 %max% 31 30 31 30 31 31 30 31 30
for %%i in (%str%) do (
set /a num+=1
if !num! leq !sm! set /a mday+=%%i
)
set /a days=days+mday+sd
set /a days-=input
rem ========把天數轉換為日期========
:: 獲取年份
for /l %%i in (1,1,%sy%) do (
set /a leap="^!(%%i %% 4) & ^!(^!(%%i %% 100)) | ^!(%%i %% 400)"
set /a days_tmp=365+leap
if !days! gtr !days_tmp! (
set /a days-=days_tmp
set y=%%i
)
)
:: 獲取月份及日期
set /a m=1, max=28+%leap%
set str=31 %max% 31 30 31 30 31 31 30 31 30
for %%i in (%str%) do (
if !days! gtr %%i (
set /a days-=%%i
set /a m+=1
) else goto next
)
:next
set m=0%m%
set d=0%days%
cls
echo.&echo.
echo 指定的日期是：%day%
echo.
echo %input% 天前的日期是：%y%-%m:~-2%-%d:~-2%
pause>nul
goto Main
代碼四、
復制代碼 代碼如下:
@echo off
:: 作者： namejm 榮譽版主 出自：cn-dos
:: 求N天前的日期
:: 思路：
:: 把當前日期轉換為天數
:: 用當前天數減去N天
:: 把結果再轉換為日期
:: 具體操作是：
: 先按照每年365天計算，然后再計算閏年的個數
:: 最后再做轉換
:: 特點：
:: 代碼復雜，不便于理解，但是速度很快
:: 計算上還存在bug，可以用 11111 來和頭兩個做對比測試，暫時沒時間更新
setlocal enabledelayedexpansion
:Main
cls
:: 日期可以帶星期，但是，必須以年月日的順序排列
:: 年份必須是四位，否則會出錯
set day=2007-01-02
set /a days=0, sum=0
echo.&echo.
echo 指定的日期是：%day%
echo.
set /p input= 請指定要追溯的天數：
rem =======把日期轉換為天數=======
:: 提取日期
for /f "tokens=1-3 delims=/-. " %%i in ("%day%") do (
set /a sy=%%i, sm=100%%j %% 100, sd=100%%k %% 100, y=%%i
)
:: 把年份抓換為天數
set num=0
if %sy% lss 400 goto next1
call :leap_num
:next1
set /a leap_num=sy/4-num
:: 把月份轉換為天數
set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
set /a max=28+leap
set num=0
set str=31 %max% 31 30 31 30 31 31 30 31 30 31
for %%i in (%str%) do (
set /a num+=1
if !num! lss %sm% set /a sum+=%%i
)
set /a days=365*sy+leap_num+sum+sd
set /a days-=input
rem =======把天數轉換為日期=======
:: 獲取年份
set /a y=days/365
set /a mod1=days %% 365
call :leap_num
set /a mod2=mod1-leap_num
:loop2
if %mod2% lss 0 (
set /a y-=1
set /a mod2=365+mod2
) else goto next2
goto loop2
:: 獲取月份及日期
:next2
set /a m=1, days=mod2+1, max=28+%leap%
set str=31 %max% 31 30 31 30 31 31 30 31 30
for %%i in (%str%) do (
if !days! gtr %%i (
set /a days-=%%i
set /a m+=1
) else goto next3
)
:next3
set m=0%m%
set d=0%days%
cls
echo.&echo.
echo 指定的日期是：%day%
echo.
echo %input% 天前的日期是：%y%-%m:~-2%-%d:~-2%
pause>nul
goto Main
:leap_num
:: 計算能被100整除但是不能被400整除的年次
set /a y_tmp=(%y:~0,1%%y%-%y%)/10
set num=0
:loop1
set /a mod=y_tmp %% 400
if %mod% neq 0 set /a num+=1
set /a y_tmp-=100
if %y_tmp% geq 100 goto loop1
set /a leap_num=y/4-num
goto :eof
代碼五、
用 vbs 代碼可以更簡單。但是需創建 tmptmp.vbs 臨時文件。
復制代碼 代碼如下:
@echo off
set /p _tian= 請指定要追溯的天數：
>tmptmp.vbs echo wscript.echo dateadd("d",-%_tian%,date)
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmptmp.vbs') do (
set /a y=%%i,m=100%%j%%100,d=100%%k%%100
)
set "difdate=%y%-%m%-%d%"
del/q tmptmp.vbs
cls&echo.&echo.
echo 指定的日期是： %date:~0,10%
echo.
echo %_tian% 天前的日期是：%difdate%
echo.&pause&exit
第一個看不大懂........
我再來補充兩個嵌vbs的：
第一個是我的，不用生成臨時文件：
復制代碼 代碼如下:
' 2>nul 3>nul&@echo off&cls
'&if not "%1"=="" goto on
'&set/p day=請輸入要追溯的天數:
'&start wscript.exe /nologo /e:vbs %0 %day%
'&exit
set oshell=createobject("wscript.shell")
d=wscript.arguments(0)
add=dateadd("d",-d,date)
myweekday=weekdayname(weekday(add))
s=wscript.scriptfullname
oshell.run "cmd /c"&""""&s&""""&" "&d&" "&add&" "&myweekday,1,false
:on error resume next
'&title 追溯日期&echo 今天是: %date%&echo.&echo %1天前是: %2 %3&echo.&pause&%0
第二個來自bbs.verybat.cn ，出自 清風09，有臨時文件：
復制代碼 代碼如下:
@echo off
set /p d=請輸入要追溯的天數:
mshta vbscript:createobject("scripting.filesystemobject").opentextfile("wind.txt",2,true).writeline(dateadd("d",-%d%,date))(window.close)
for /f %%a in (wind.txt) do echo %d%天前為:%%a
pause>nul & del wind.txt
