@echo off & setlocal ENABLEEXTENSIONS

:: ---------- 配置項(xiàng) ----------

:: 備份放置的路徑，加 /
set BACKUP_PATH=D:/Backup/

:: 要備份的數(shù)據(jù)庫名稱，多個(gè)用空格分隔
set DATABASES=database1 database2 database3

:: MySQL 用戶名
set USERNAME=root

:: MySQL 密碼
set PASSWORD=123456

:: MySQL Bin 目錄，加 /
:: 如果可以直接使用 mysqldump（安裝時(shí)添加 MySQL Bin 目錄到了環(huán)境變量），此處留空即可
set MYSQL=D:/SERVER/MySQL/bin/

:: WinRAR 自帶命令行工具的可執(zhí)行文件路徑，長文件名注意用 Dos 長文件名書寫方式
set WINRAR=C:/Progra~1/WinRAR/Rar.exe

:: ---------- 以下請勿修改 ----------

set YEAR=%date:~0,4%
set MONTH=%date:~5,2%
set DAY=%date:~8,2%
:: 如果在 dos 下輸入 time 返回的不是 24 小時(shí)制（沒有 0 填充），請自行修改此處
set HOUR=%time:~0,2%
set MINUTE=%time:~3,2%
set SECOND=%time:~6,2%

set DIR=%BACKUP_PATH%%YEAR%/%MONTH%/%DAY%/
set ADDON=%YEAR%%MONTH%%DAY%%HOUR%%MINUTE%%SECOND%

:: create dir
if not exist %DIR% (
mkdir %DIR% 2>nul
)
if not exist %DIR% (
echo Backup path: %DIR% not exists, create dir failed.
goto exit
)
cd /d %DIR%

:: backup
echo Start dump databases...
for %%D in (%DATABASES%) do (
echo Dumping database %%D ...
%MYSQL%mysqldump -u%USERNAME% -p%PASSWORD% %%D > %%D.%ADDON%.sql 2>nul
:: winrar
if exist %WINRAR% (
%WINRAR% a -k -r -s -m1 -ep1 %%D.%ADDON%.rar %%D.%ADDON%.sql 2>nul
del /F /S /Q %%D.%ADDON%.sql 2>nul
)
)
echo Done

:exit

@echo off

:: ------- 配置項(xiàng) -------

:: 要執(zhí)行的文件名
set FILE=D:/cron/cron_backup.bat

:: 計(jì)劃頻率類型
set FREQUENCY=DAILY

:: 頻率，與上面的計(jì)劃頻率類型對應(yīng)
set MODIFIER=1

:: 該計(jì)劃執(zhí)行的時(shí)間（24 小時(shí)制）
set DATETIME=00:30:00

:: 計(jì)劃的名字
set NAME="Backup Cron Job"

:: 計(jì)劃執(zhí)行用戶，不建議修改
set USER="System"

:: ------- 以下請勿修改 -------

schtasks /Create /RU %USER% /SC %FREQUENCY% /MO %MODIFIER% /ST %DATETIME% /TN %NAME% /TR %FILE%
pause