(七)抓取圖標(biāo)（ICON）的窗體
創(chuàng)建一個(gè)新的Form3，保存為Capture3.pas。設(shè)置屬性BorderIcons的四個(gè)屬性為false.
BorderStyle設(shè)為bsNone,FormStyle設(shè)為fsStayOnTop.
一個(gè)私有變量：fDragging:Boolean; 兩個(gè)公共變量:fRect:TRect,fBmp:TBitmap;

unit Capture3;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;

type
  TForm3 = class(TForm)
    PRocedure FormCreate(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState;
                 X,  Y: Integer);
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormActivate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormPaint(Sender: TObject);
  private
    fDragging:Boolean;
  public
    fRect:TRect;
    fBmp:TBitmap;
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

//創(chuàng)建一個(gè)新的自定義光標(biāo)CURSOR_2,放在Capture3.res資源
//文件中.是32*32的白色矩形邊框，用來指示抓圖的范圍.
procedure TForm3.FormCreate(Sender: TObject);
var aDC:HDC ;
const crBox = -19;
begin
  Screen.Cursors[crBox]:=LoadCursor(hInstance,'CURSOR_2');
  Cursor := crBox;
  fBmp := TBitmap.Create ;
  fBmp.Width := Screen.Width ;
  fBmp.Height:= Screen.Height;
  aDC := GetDC(0);
  BitBlt(fBmp.Canvas.Handle,0,0,Screen.Width,Screen.Height,aDC,0,0,srcCopy);
  ReleaseDC(0,aDC);
  SetBounds(0,0,Screen.Width,Screen.Height);
end;

procedure TForm3.FormMouseDown(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  if mbLeft = Button then begin
    fDragging := true;
    SetRect(fRect,X,Y,X+32,Y+32);
    Canvas.DrawFocusRect(fRect);
  end;
end;

procedure TForm3.FormMouseMove(Sender: TObject; Shift: TShiftState;
         X, Y: Integer);
begin
  if fDragging then begin
    Canvas.DrawFocusRect(fRect);
    fRect.Left := X ;
    fRect.Top  := Y ;
    fRect.Right:= X+32;
    fRect.Bottom:=Y+32;
    Canvas.DrawFocusRect(fRect); 
  end;
end;

procedure TForm3.FormMouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  ModalResult:=mrOK;
end;

procedure TForm3.FormActivate(Sender: TObject);
const crHand=-18;
begin
  Screen.Cursors[crHand]:=LoadCursor(hInstance,pChar('CURSOR_1'));
  Cursor:=crHand;
end;

procedure TForm3.FormDestroy(Sender: TObject);
begin
  fBmp.Free;
  Screen.Cursor := crDefault;
end;

procedure TForm3.FormPaint(Sender: TObject);
begin
  Canvas.Draw(0,0,fBmp);
end;

end.