Delphi中的線程類--之（1）
Delphi中的線程類--之（1）    Raptor（原作）  
  
關(guān)鍵字     Thread Event CriticalSection Synchronize 
  
Delphi中的線程類

猛禽[Mental Studio]

http://mental.mentsu.com

（ 之一）

Delphi中有一個線程類TThread是用來實(shí)現(xiàn)多線程編程的，這個絕大多數(shù)Delphi書藉都有說到，但基本上都是對TThread類的幾個成員作一簡單介紹，再說明一下Execute的實(shí)現(xiàn)和Synchronize的用法就完了。然而這并不是多線程編程的全部，我寫此文的目的在于對此作一個補(bǔ)充。

線程本質(zhì)上是進(jìn)程中一段并發(fā)運(yùn)行的代碼。一個進(jìn)程至少有一個線程，即所謂的主線程。同時還可以有多個子線程。當(dāng)一個進(jìn)程中用到超過一個線程時，就是所謂的“多線程”。

那么這個所謂的“一段代碼”是如何定義的呢？其實(shí)就是一個函數(shù)或過程（對Delphi而言）。

如果用Windows API來創(chuàng)建線程的話，是通過一個叫做CreateThread的API函數(shù)來實(shí)現(xiàn)的，它的定義為：

HANDLE CreateThread(
    LPSECURITY_ATTRIBUTES lpThreadAttributes, 
    DWord dwStackSize, 
    LPTHREAD_START_ROUTINE lpStartAddress, 
    LPVOID lpParameter, 
    DWORD dwCreationFlags, 
    LPDWORD lpThreadId 
   );

其各參數(shù)如它們的名稱所說，分別是：線程屬性（用于在NT下進(jìn)行線程的安全屬性設(shè)置，在9X下無效），堆棧大小，起始地址，參數(shù)，創(chuàng)建標(biāo)志（用于設(shè)置線程創(chuàng)建時的狀態(tài)），線程ID，最后返回線程Handle。其中的起始地址就是線程函數(shù)的入口，直至線程函數(shù)結(jié)束，線程也就結(jié)束了。
整個線程的執(zhí)行過程如下圖：
此主題相關(guān)圖片如下：

因?yàn)?/SPAN>CreateThread參數(shù)很多，而且是Windows的API，所以在C Runtime Library里提供了一個通用的線程函數(shù)（理論上可以在任何支持線程的OS中使用）：

unsigned long _beginthread(void (_USERENTRY *__start)(void *), unsigned __stksize, void *__arg);

Delphi也提供了一個相同功能的類似函數(shù)：

function BeginThread(SecurityAttributes: Pointer; StackSize: LongWord; ThreadFunc: TThreadFunc; Parameter: Pointer; CreationFlags: LongWord; var ThreadId: LongWord): Integer;

這三個函數(shù)的功能是基本相同的，它們都是將線程函數(shù)中的代碼放到一個獨(dú)立的線程中執(zhí)行。線程函數(shù)與一般函數(shù)的最大不同在于，線程函數(shù)一啟動，這三個線程啟動函數(shù)就返回了，主線程繼續(xù)向下執(zhí)行，而線程函數(shù)在一個獨(dú)立的線程中執(zhí)行，它要執(zhí)行多久，什么時候返回，主線程是不管也不知道的。

正常情況下，線程函數(shù)返回后，線程就終止了。但也有其它方式：

Windows API：

VOID ExitThread( DWORD dwExitCode );
C Runtime Library：

void _endthread(void);

Delphi Runtime Library：

PRocedure EndThread(ExitCode: Integer);

為了記錄一些必要的線程數(shù)據(jù)（狀態(tài)/屬性等），OS會為線程創(chuàng)建一個內(nèi)部Object，如在Windows中那個Handle便是這個內(nèi)部Object的Handle，所以在線程結(jié)束的時候還應(yīng)該釋放這個Object。

 

雖然說用API或RTL(Runtime Library)已經(jīng)可以很方便地進(jìn)行多線程編程了，但是還是需要進(jìn)行較多的細(xì)節(jié)處理，為此Delphi在Classes單元中對線程作了一個較好的封裝，這就是VCL的線程類：TThread

使用這個類也很簡單，大多數(shù)的Delphi書籍都有說，基本用法是：先從TThread派生一個自己的線程類（因?yàn)?/SPAN>TThread是一個抽象類，不能生成實(shí)例），然后是Override抽象方法：Execute（這就是線程函數(shù)，也就是在線程中執(zhí)行的代碼部分），如果需要用到可視VCL對象，還需要通過Synchronize過程進(jìn)行。關(guān)于之方面的具體細(xì)節(jié)，這里不再贅述，請參考相關(guān)書籍。

本文接下來要討論的是TThread類是如何對線程進(jìn)行封裝的，也就是深入研究一下TThread類的實(shí)現(xiàn)。因?yàn)橹皇钦嬲亓私饬怂鸥玫厥褂盟?/SPAN>

下面是DELPHI7中TThread類的聲明（本文只討論在Windows平臺下的實(shí)現(xiàn)，所以去掉了所有有關(guān)linux平臺部分的代碼）：

  TThread = class
  private
    FHandle: THandle;
    FThreadID: THandle;
    FCreateSuspended: Boolean;
    FTerminated: Boolean;
    FSuspended: Boolean;
    FFreeOnTerminate: Boolean;
    FFinished: Boolean;
    FReturnValue: Integer;
    FOnTerminate: TNotifyEvent;
    FSynchronize: TSynchronizeRecord;
    FFatalException: TObject;
    procedure CallOnTerminate;
    class procedure Synchronize(ASyncRec: PSynchronizeRecord); overload;
    function GetPriority: TThreadPriority;
    procedure SetPriority(Value: TThreadPriority);
    procedure SetSuspended(Value: Boolean);

  protected
    procedure CheckThreadError(ErrCode: Integer); overload;
    procedure CheckThreadError(Success: Boolean); overload;
   procedure DoTerminate; virtual;
    procedure Execute; virtual; abstract;
    procedure Synchronize(Method: TThreadMethod); overload;
    property ReturnValue: Integer read FReturnValue write FReturnValue;
    property Terminated: Boolean read FTerminated;

  public
    constructor Create(CreateSuspended: Boolean);
    destructor Destroy; override;
    procedure AfterConstruction; override;
    procedure Resume;
    procedure Suspend;
    procedure Terminate;
    function WaitFor: LongWord;
    class procedure Synchronize(AThread: TThread; AMethod: TThreadMethod); overload;
    class procedure StaticSynchronize(AThread: TThread; AMethod: TThreadMethod);
    property FatalException: TObject read FFatalException;
    property FreeOnTerminate: Boolean read FFreeOnTerminate write FFreeOnTerminate;
    property Handle: THandle read FHandle;
    property Priority: TThreadPriority read GetPriority write SetPriority;
    property Suspended: Boolean read FSuspended write SetSuspended;
    property ThreadID: THandle read FThreadID;
    property OnTerminate: TNotifyEvent read FOnTerminate write FOnTerminate;
  end;

TThread類在Delphi的RTL里算是比較簡單的類，類成員也不多，類屬性都很簡單明白，本文將只對幾個比較重要的類成員方法和唯一的事件：OnTerminate作詳細(xì)分析。

（待續(xù)）
 

Delphi中的線程類--之（2）
 Delphi中的線程類--之（2）    Raptor（原作）  
  
關(guān)鍵字     Thread Event CriticalSection Synchronize 
  
Delphi中的線程類

猛禽[Mental Studio]

http://mental.mentsu.com

之二

首先就是構(gòu)造函數(shù)：

constructor TThread.Create(CreateSuspended: Boolean);
begin
  inherited Create;
  AddThread;
  FSuspended := CreateSuspended;
  FCreateSuspended := CreateSuspended;
  FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), CREATE_SUSPENDED, FThreadID);
  if FHandle = 0 then
    raise EThread.CreateResFmt(@SThreadCreateError, [SysErrorMessage(GetLastError)]);
end;

雖然這個構(gòu)造函數(shù)沒有多少代碼，但卻可以算是最重要的一個成員，因?yàn)榫€程就是在這里被創(chuàng)建的。

在通過Inherited調(diào)用TObject.Create后，第一句就是調(diào)用一個過程：AddThread，其源碼如下：

procedure AddThread;
begin
  InterlockedIncrement(ThreadCount);
end;

同樣有一個對應(yīng)的RemoveThread：
procedure RemoveThread;
begin
  InterlockedDecrement(ThreadCount);
end;

它們的功能很簡單，就是通過增減一個全局變量來統(tǒng)計進(jìn)程中的線程數(shù)。只是這里用于增減變量的并不是常用的Inc/Dec過程，而是用了InterlockedIncrement/InterlockedDecrement這一對過程，它們實(shí)現(xiàn)的功能完全一樣，都是對變量加一或減一。但它們有一個最大的區(qū)別，那就是InterlockedIncrement/InterlockedDecrement是線程安全的。即它們在多線程下能保證執(zhí)行結(jié)果正確，而Inc/Dec不能。或者按操作系統(tǒng)理論中的術(shù)語來說，這是一對“原語”操作。

以加一為例來說明二者實(shí)現(xiàn)細(xì)節(jié)上的不同：

一般來說，對內(nèi)存數(shù)據(jù)加一的操作分解以后有三個步驟：

1、  從內(nèi)存中讀出數(shù)據(jù)
2、  數(shù)據(jù)加一
3、  存入內(nèi)存

現(xiàn)在假設(shè)在一個兩個線程的應(yīng)用中用Inc進(jìn)行加一操作可能出現(xiàn)的一種情況：
1、  線程A從內(nèi)存中讀出數(shù)據(jù)（假設(shè)為3）
2、  線程B從內(nèi)存中讀出數(shù)據(jù)（也是3）
3、  線程A對數(shù)據(jù)加一（現(xiàn)在是4）
4、  線程B對數(shù)據(jù)加一（現(xiàn)在也是4）
5、  線程A將數(shù)據(jù)存入內(nèi)存（現(xiàn)在內(nèi)存中的數(shù)據(jù)是4）
6、  線程B也將數(shù)據(jù)存入內(nèi)存（現(xiàn)在內(nèi)存中的數(shù)據(jù)還是4，但兩個線程都對它加了一，應(yīng)該是5才對，所以這里出現(xiàn)了錯誤的結(jié)果）

而用InterlockIncrement過程則沒有這個問題，因?yàn)樗^“原語”是一種不可中斷的操作，即操作系統(tǒng)能保證在一個“原語”執(zhí)行完畢前不會進(jìn)行線程切換。所以在上面那個例子中，只有當(dāng)線程A執(zhí)行完將數(shù)據(jù)存入內(nèi)存后，線程B才可以開始從中取數(shù)并進(jìn)行加一操作，這樣就保證了即使是在多線程情況下，結(jié)果也一定會是正確的。

前面那個例子也說明一種“線程訪問沖突”的情況，這也就是為什么線程之間需要“同步”（Synchronize），關(guān)于這個，在后面說到同步時還會再詳細(xì)討論。

說到同步，有一個題外話：加拿大滑鐵盧大學(xué)的教授李明曾就Synchronize一詞在“線程同步”中被譯作“同步”提出過異議，個人認(rèn)為他說的其實(shí)很有道理。在中文中“同步”的意思是“同時發(fā)生”，而“線程同步”目的就是避免這種“同時發(fā)生”的事情。而在英文中，Synchronize的意思有兩個：一個是傳統(tǒng)意義上的同步（To occur at the same time），另一個是“協(xié)調(diào)一致”（To Operate in unison）。在“線程同步”中的Synchronize一詞應(yīng)該是指后面一種意思，即“保證多個線程在訪問同一數(shù)據(jù)時，保持協(xié)調(diào)一致，避免出錯”。不過像這樣譯得不準(zhǔn)的詞在IT業(yè)還有很多，既然已經(jīng)是約定俗成了，本文也將繼續(xù)沿用，只是在這里說明一下，因?yàn)檐浖_發(fā)是一項細(xì)致的工作，該弄清楚的，絕不能含糊。

扯遠(yuǎn)了，回到TThread的構(gòu)造函數(shù)上，接下來最重要就是這句了：

FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), CREATE_SUSPENDED, FThreadID);

這里就用到了前面說到的Delphi RTL函數(shù)BeginThread，它有很多參數(shù)，關(guān)鍵的是第三、四兩個參數(shù)。第三個參數(shù)就是前面說到的線程函數(shù)，即在線程中執(zhí)行的代碼部分。第四個參數(shù)則是傳遞給線程函數(shù)的參數(shù)，在這里就是創(chuàng)建的線程對象（即Self）。其它的參數(shù)中，第五個是用于設(shè)置線程在創(chuàng)建后即掛起，不立即執(zhí)行（啟動線程的工作是在AfterConstruction中根據(jù)CreateSuspended標(biāo)志來決定的），第六個是返回線程ID。

現(xiàn)在來看TThread的核心：線程函數(shù)ThreadProc。有意思的是這個線程類的核心卻不是線程的成員，而是一個全局函數(shù)（因?yàn)?/SPAN>BeginThread過程的參數(shù)約定只能用全局函數(shù)）。下面是它的代碼：

function ThreadProc(Thread: TThread): Integer;
var
  FreeThread: Boolean;
begin
  try
    if not Thread.Terminated then
    try
      Thread.Execute;
    except
      Thread.FFatalException := AcquireExceptionObject;
    end;
  finally
    FreeThread := Thread.FFreeOnTerminate;
    Result := Thread.FReturnValue;
    Thread.DoTerminate;
    Thread.FFinished := True;
    SignalSyncEvent;
    if FreeThread then Thread.Free;
    EndThread(Result);
  end;
end;

雖然也沒有多少代碼，但卻是整個TThread中最重要的部分，因?yàn)檫@段代碼是真正在線程中執(zhí)行的代碼。下面對代碼作逐行說明：

首先判斷線程類的Terminated標(biāo)志，如果未被標(biāo)志為終止，則調(diào)用線程類的Execute方法執(zhí)行線程代碼，因?yàn)?/SPAN>TThread是抽象類，Execute方法是抽象方法，所以本質(zhì)上是執(zhí)行派生類中的Execute代碼。

所以說，Execute就是線程類中的線程函數(shù)，所有在Execute中的代碼都需要當(dāng)作線程代碼來考慮，如防止訪問沖突等。

如果Execute發(fā)生異常，則通過AcquireExceptionObject取得異常對象，并存入線程類的FFatalException成員中。

最后是線程結(jié)束前做的一些收尾工作。局部變量FreeThread記錄了線程類的FreeOnTerminated屬性的設(shè)置，然后將線程返回值設(shè)置為線程類的返回值屬性的值。然后執(zhí)行線程類的DoTerminate方法。

DoTerminate方法的代碼如下：
procedure TThread.DoTerminate;
begin
  if Assigned(FOnTerminate) then Synchronize(CallOnTerminate);
end;

很簡單，就是通過Synchronize來調(diào)用CallOnTerminate方法，而CallOnTerminate方法的代碼如下，就是簡單地調(diào)用OnTerminate事件：

procedure TThread.CallOnTerminate;
begin
  if Assigned(FOnTerminate) then FOnTerminate(Self);
end;

因?yàn)?/SPAN>OnTerminate事件是在Synchronize中執(zhí)行的，所以本質(zhì)上它并不是線程代碼，而是主線程代碼（具體見后面對Synchronize的分析）。

執(zhí)行完OnTerminate后，將線程類的FFinished標(biāo)志設(shè)置為True。

接下來執(zhí)行SignalSyncEvent過程，其代碼如下：

procedure SignalSyncEvent;
begin
  SetEvent(SyncEvent);
end;

也很簡單，就是設(shè)置一下一個全局Event：SyncEvent，關(guān)于Event的使用，本文將在后文詳述，而SyncEvent的用途將在WaitFor