用Delphi做一個(gè)有顏色屬性的按鈕

http://www.netgocn.com 原創(chuàng)

在標(biāo)準(zhǔn)的Windows程序中所有按鈕均沒有顏色。因此Delphi提供的所有按鈕組件也均無顏色屬性，有時(shí)你可能做了一個(gè)五顏六色的程序界面，而按鈕顏色可能很不相稱。
    在此本人提供一種用自定義組件制作有顏色屬性的銨鈕的方法，它遵循了Delphi的組件定義規(guī)則，完成后該按鈕與普通按鈕（Button）相比，多了一個(gè)Color屬性，你可以永遠(yuǎn)地使用它，在設(shè)計(jì)階段隨意地改變顏色，就象是Delphi本身提供的組件一樣（本文代碼在Delphi 4.0下完成)。
第一步
    打開Delphi，選擇菜單的Component/New Component選項(xiàng)，在彈出對(duì)話框的Ancestor type下拉框中手工填入或下拉選擇TButton，這是選擇了我們自定義組件的祖先類，我們將以此為基礎(chǔ)完成自定義組件的下一步代碼編寫（這也是自定義組件編寫的第一步）。對(duì)話框中的其余可編寫內(nèi)容就隨你的高興而填寫了，但是你必須注意Class Name(類名）不能和已有的（包括你自定義的）類名相同，同時(shí)還應(yīng)該記住該自定義組件的安裝位置(Palette Page下拉框中的內(nèi)容)和單元文件在磁盤上的存放位置(Unit file name編輯框內(nèi)容)，不然以后你在何處去找它?本文以 Delphi的默認(rèn)值TButton1為類名。
第二步
    做完以上工作后，按下面的OK按鈕，Delphi將為你自動(dòng)生成一個(gè)基本的組件代碼，對(duì)這樣的代碼框架一般沒有必要修改，一定要修改的話請注意Delphi的組件定義規(guī)則（本文只是刪除了所有自動(dòng)生成的注釋內(nèi)容），接著就應(yīng)該將其文件存盤。
第三步
    在上面的代碼框架中添加我們的代碼，當(dāng)然這是我們要做的主要工作。

1.      將Delphi自動(dòng)生成的單元文件的數(shù)據(jù)類型定義部份修改為：
type
TButton1 = class(TButton)
PRivate
  FColor:TColor;
  FCanvas: TCanvas;
  IsFocused: Boolean;
  procedure SetColor(Value:TColor);
  procedure CNDrawItem(var Message: TWMDrawItem); message CN_DRAWITEM;
protected
  procedure CreateParams(var Params: TCreateParams); override;
  procedure SetButtonStyle(ADefault: Boolean); override;
public
  constructor Create(AOwner: TComponent); override;
  destructor Destroy; override;
published
  property Color:TColor read FColor write SetColor default clWhite;
end;
說明：
    a. 我們只添加了一個(gè)屬性，因此在published段的代碼下只有一個(gè)Color屬性，并將默認(rèn)顏色設(shè)為白色（clWhite，當(dāng)然你可以隨意改變)。
    b. 重載構(gòu)造函數(shù)和析構(gòu)函數(shù)，二者應(yīng)為可以在外部調(diào)用，因此應(yīng)將其放在public段。
    c. 讀屬性的私有數(shù)據(jù)域FColor和屬性的寫方法SetColor，應(yīng)放在私有段(private)，其它與此相關(guān)的非獨(dú)立的變量和過程/函數(shù)等也應(yīng)放在private段，以使在類以外不能訪問它們。

2.      Delphi自動(dòng)生成的 procedure Register可以不理它。我們在它的過程體之后，在end.(注意符號(hào)“.”)之前手工加上以下代碼，完成我們在上面定義的全部過程的過程體編寫（這里我們沒有定義有函數(shù)原型）：

//*** 構(gòu)造函數(shù) *****************************************************
constructor TButton1.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FCanvas := TCanvas.Create;
  FColor:=clWhite;//默認(rèn)顏色
end;

//*** 析構(gòu)函數(shù) *************************************************
destructor TButton1.Destroy;
begin
  FCanvas.Free;
  inherited Destroy;
end;

//*** 定義按鈕樣式，必須將該按鈕重定義為自繪式按鈕 *************
procedure TButton1.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  with Params do Style := Style or BS_OWNERDRAW;
end;

//*** 屬性寫方法 ************************************************
procedure TButton1.SetColor(Value:TColor);
begin
  FColor:=Value;
  Invalidate;
end;

//*** 設(shè)置按鈕狀態(tài)***********************************************
procedure TButton1.SetButtonStyle(ADefault: Boolean);
begin
  if ADefault <> IsFocused then
  begin
    IsFocused := ADefault;
    Refresh;
  end;
end;

//*** 繪制按鈕 ***************************************************
procedure TButton1.CNDrawItem(var Message: TWMDrawItem);
var
  IsDown, IsDefault: Boolean;
  ARect: TRect;
  Flags: Longint;
  DrawItemStruct: TDrawItemStruct;
  wh:TSize;
begin
  DrawItemStruct:=Message.DrawItemStruct^;
  FCanvas.Handle := DrawItemStruct.hDC;
  ARect := ClientRect;
  with DrawItemStruct do
  begin
    IsDown := itemState and ODS_SELECTED <> 0;
    IsDefault := itemState and ODS_FOCUS <> 0;
  end;

  Flags := DFCS_BUTTONPUSH or DFCS_ADJUSTRECT;
  if IsDown then Flags := Flags or DFCS_PUSHED;
  if DrawItemStruct.itemState and ODS_DISABLED <> 0 then
     Flags := Flags or DFCS_INACTIVE;

  if IsFocused or IsDefault then
  begin
    //按鈕得到焦點(diǎn)時(shí)的狀態(tài)繪制
    FCanvas.Pen.Color := clWindowFrame;
    FCanvas.Pen.Width := 1;
    FCanvas.Brush.Style := bsClear;
    FCanvas.Rectangle(ARect.Left, ARect.Top, ARect.Right, ARect.Bottom);
    InflateRect(ARect, -1, -1);
  end;

  FCanvas.Pen.Color := clBtnShadow;
  FCanvas.Pen.Width := 1;
  FCanvas.Brush.Color := FColor;
  if IsDown then begin
    //按鈕被按下時(shí)的狀態(tài)繪制
     FCanvas.Rectangle(ARect.Left , ARect.Top, ARect.Right, ARect.Bottom);
     InflateRect(ARect, -1, -1);
  end else
     //繪制一個(gè)未按下的按鈕
     DrawFrameControl(DrawItemStruct.hDC, ARect, DFC_BUTTON, Flags);
  FCanvas.FillRect(ARect);

  //繪制Caption文本內(nèi)容
  FCanvas.Font := Self.Font;
  ARect:=ClientRect;
  wh:=FCanvas.TextExtent(Caption);
  FCanvas.Pen.Width := 1;
  FCanvas.Brush.Style := bsClear;
  if not Enabled then
  begin //按鈕失效時(shí)應(yīng)多繪一次Caption文本
     FCanvas.Font.Color := clBtnHighlight;
     FCanvas.TextOut((Width div 2)-(wh.cx div 2)+1,
                     (height div 2)-(wh.cy div 2)+1,
                      Caption);
     FCanvas.Font.Color := clBtnShadow;
  end;
  FCanvas.TextOut((Width div 2)-(wh.cx div 2),(height div 2)-(wh.cy div 2),Caption);

  //繪制得到焦點(diǎn)時(shí)的內(nèi)框虛線
  if IsFocused and IsDefault then
  begin
     ARect := ClientRect;
     InflateRect(ARect, -4, -4);
     FCanvas.Pen.Color := clWindowFrame;
     FCanvas.Brush.Color := FColor;
     DrawFocusRect(FCanvas.Handle, ARect);
  end;
  FCanvas.Handle := 0;
end;
//** The End *********************************************************
end.

第四步：檢查確認(rèn)無誤后選擇Delphi菜單的Component/Install Component選項(xiàng)，在Unite file name編輯框中確認(rèn)你的文件路徑和名稱后按OK按鈕，Delphi將編譯、安裝該組件。
      如果你完全按本文步聚進(jìn)行，在編譯安裝無誤后，你可以在Delphi組件標(biāo)簽的Samples標(biāo)簽頁中找到一個(gè)圖標(biāo)和TButton一樣的按鈕。新建一個(gè)工程并將這個(gè)我們自義的按鈕放置在Form上其默認(rèn)的名稱是Button11，你會(huì)看到一個(gè)白色的按鈕。怎么樣？通過其Color屬性你以隨意設(shè)置它的顏色。
      最后說明：本文中的按鈕繪制方式采用了和Delphi本身的TButton相似的繪制方式，以達(dá)到和Delphi按鈕相似的動(dòng)作外觀。然而你想要發(fā)揮的話你可以在FCanvas這塊畫布上繪制任意的、你想要的、可以表達(dá)你的個(gè)性的所有文字和圖形。

 有何問題請來信或留言。
歡迎試用本站軟件：NetGoCN(網(wǎng)行)